[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: Harddrive on a II+???
- Subject: Re: Harddrive on a II+???
- From: casa@unm.edu (Jim Pittman)
- Date: 1999/03/09
- Newsgroups: comp.sys.apple2
- Organization: University of New Mexico, Albuquerque
- Summary: (long)
Paul Grammens <pgrammen@sonic.net> wrote:
: Subject: Re: Harddrive on a II+??? Date: Tue, 09 Mar 1999 08:51:08
: Newsgroups: comp.sys.apple2
: Organization: Sonic,Santa Rosa CA,http://www.sonic.net
:
: Jim Pittman wrote:
:> I wrote a simple HELLO program to act as a menu-driven program
:> selector and it resides on a DOS 3.3 disk in Slot 6 Drive 1. When
:> the computer starts up, the disk in Slot 6 Drive 1 boots up to the
:> menu. One item on the menu starts up a binary copy of Super-Text,
:> a DOS 3.3 word processor. Another menu item starts up Softerm-2, a
:> DOS 3.3 terminal emulation program. Another menu item boots the
:> hard drive in Slot 7.
:
: This is interesting stuff. I have a II+ and a Franklin 1000 that is
: functionally a II+, and have been struggling to find something that
: will run on them. How do you create/edit those HELLO programs? Could
: you post a sample of the code?
:
: I have a IIgs, IIe with Transwarp (LOVE to see that start up!), IIe
: Enhanced, IIc, and IIc Plus, and mostly play with those, but the
: Franklin has a 300 baud Hayes modem in it and I'd get a kick out of
: logging in to the net with it. I'm going to poke around to see if I
: can find any of those programs you mentioned. Thanks for posting all
: that detail.
:
: -Paul
Okay, here are model programs. The first one is a "HELLO" program on
a 5.25" DOS 3.3 formatted disk in Slot 6, Drive 1 on the Apple II Plus
and this is the program that runs when the computer is turned on:
100 REM " SOFTERM-2 and SUPER-TEXT Program Disk "
110 REM
120 REM " The HELLO program selects which program to run. "
130 REM " SUPER-TEXT binary files were copied by WILDCARD-2. "
140 REM " SOFTERM-2 program files are those needed for VT-100 "
150 REM " terminal emulation on the Apple II Plus with Videx "
160 REM " UltraTerm 80-column card. "
170 REM
180 REM " =====> Clear screen "
190 REM
200 TEXT : HOME : PRINT CHR$ (12)
210 REM
220 REM " =====> Main Menu "
230 REM
240 TEXT : HOME : PRINT CHR$ (12)
250 PRINT "======================================="
260 PRINT "| |"
270 PRINT "| Softerm-2 and Super-Text |"
280 PRINT "| |"
290 PRINT "| for Apple II Plus with UltraTerm |"
300 PRINT "| |"
310 PRINT "======================================="
320 PRINT "< t > Terminal emulation .... Softerm-2"
330 PRINT "< w > Word processor Super-Text DOS 3.3"
340 PRINT "< f > Boot Focus hard drive in Slot 7 "
350 PRINT "< q > Quit to DOS 3.3 - Applesoft BASIC"
360 PRINT "======================================="
370 PRINT "Select: ";
380 REM
390 REM " =====> Select from Main Menu "
410 GET A$
420 IF (A$ = "t" OR A$ = "T") THEN 480
430 IF (A$ = "w" OR A$ = "W") THEN 520
440 IF (A$ = "f" OR A$ = "F" OR A$ = "7") THEN 560
450 IF (A$ = "q" OR A$ = "Q") THEN 600
460 GOTO 220
470 REM
480 REM " =====> Terminal Emulator "
490 REM
500 PRINT : PRINT CHR$ (4);"BRUN SOFTERM BOOT"
510 REM
520 REM " =====> Word Processor "
530 REM
540 PRINT : PRINT CHR$ (4);"BRUN SUPER.TEXT"
550 REM
560 REM " =====> Boot Slot 7 "
570 REM
580 PRINT : PRINT CHR$ (4);"PR#7"
590 END
600 REM " =====> End of Program "
610 HOME
620 PRINT : PRINT "To restart menu, type 'RUN 200'."
999 END
The 5.25" disk contains a binary version of Super-Text made with the
help of a Wildcard copy card and several SOFTERM-2 files to allow the
Apple II Plus with UltraTerm to do VT-100 terminal emulation.
If "f" or "F" or "7" is pressed, then the Focus drive (with version
1.9 of ProDOS) boots and runs the following "STARTUP" BASIC program:
100 REM " Selector program for hard drive on Apple II Plus "
110 REM
120 REM " =====> Clear screen "
130 REM
140 TEXT : HOME : PRINT CHR$ (12)
150 REM
160 REM " =====> Main Menu "
170 REM
180 PRINT "======================================="
190 PRINT "| |"
200 PRINT "| Please select desired application...|"
210 PRINT "| |"
220 PRINT "======================================="
230 PRINT "< a > AppleWorks Word Processing"
240 PRINT "< c > Copy II Plus Disk Utilities"
270 PRINT "< b > Boot 5.25 disk in Slot 6 Drive 1"
280 PRINT "< q > Quit to ProDOS, Applesoft BASIC"
290 PRINT "======================================="
300 PRINT "Select: ";
310 REM
320 REM " =====> Select from Main Menu "
340 GET A$
350 IF (A$ = "a" OR A$ = "A") THEN 440
360 IF (A$ = "c" OR A$ = "C") THEN 530
390 IF (A$ = "b" OR A$ = "B" OR A$ = "6") THEN 670
410 IF (A$ = "q" OR A$ = "Q") THEN 710
420 GOTO 140
440 REM " =====> AppleWorks "
450 REM
510 PRINT : PRINT CHR$ (4);"BRUN APPLEWORKS/APLWORKS.SYSTEM"
520 REM
530 REM " =====> Copy II Plus "
540 REM
560 PRINT CHR$ (4);"BRUN COPYIIPLUS/UTIL.SYSTEM"
600 REM
670 REM " =====> Boot 5.25" disk in Slot 6 "
680 REM
690 PRINT : PRINT CHR$ (4);"PR#6"
600 REM
710 REM " =====> End of Program "
720 HOME
730 PRINT "To restart menu, type 'RUN'."
999 END
The Focus drive contains:
PRODOS SYS
BASIC.SYSTEM SYS
STARTUP BAS
APPLEWORKS DIR various AppleWorks files in here
COPYIIPLUS DIR various Copy II Plus files in here
DATA DIR various data folders/files in here
(Actually, since the Apple II Plus is at home and I'm at work, I am
trying to remember the setup on the II Plus based on what I see on an
enhanced Apple IIe with a Focus drive... so a few of the details may
be somewhat different from what I've outlined above. Also, since the
Apple II Plus has a TransWarp accelerator, it may actually be using
version 2.x of ProDOS... I just don't remember. I do remember, though,
that running Videx-patched AppleWorks on the II Plus is no fun.)
Jim Pittman - AppleQuerque Computer Club - where owners/users of real
Apple II computers are an endangered species now. casa AT unm DOT edu
--