[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: Apple II Music Video - Welcome to the Jungle!!
David Wilson wrote:
Michael J. Mahon wrote:
The troublesome one, which Frank already knows about, is that ProDOS
is reluctant to trample on the primary text page, so double buffering
awaits a fix for that problem...
With good reason - the screen holes can be very important to your disk
controller's operation...
If you want to try it, clear bits 0-3 in $BF58.
Right. And they seem not to cause much trouble for Oasis (!).
Here is the double-buffered (page-flipping) version of the player:
10 REM **********************
20 REM * *
30 REM * Move Movie Frames *
40 REM * by Frank Milliron *
50 REM * (modified by MJM) *
60 REM **********************
70 :
80 D$ = CHR$ (4)
85 IF PEEK (104) < > 32 THEN POKE 104,32: POKE 32 * 256,0: PRINT
D$"-play.movie"
90 BX = 3072: REM $400 + $800
100 GS = 49235: REM Graphics softswitch base address
110 FS = 1024: REM frame size
120 MV$ = "movie": REM (Or use dialog to select movie.)
130 FR = 6826: REM (Or first two bytes could be number of frames.)
140 GR : REM Set Graphics page 1 and clear
150 POKE GS - 1,0: REM Select nomix
160 BY = 0: REM Initial byte offset
170 BF = 2048:GP = 2: REM $800 for first frame
180 POKE 48984,192: REM De-protect Primary text page
190 :
200 FOR I = 1 TO FR: REM Loop over all frames
210 PRINT D$"BLOAD "MV$",b"BY",l$400,a"BF
220 POKE GS + GP,0: REM Select loaded page
230 BY = BY + FS: REM Advance to next page offset
240 BF = BX - BF: REM Toggle GR pages ($800/$400)
250 GP = 3 - GP: REM Toggle GR page numbers (2/1)
260 NEXT
270 POKE 48984,207: REM Re-protect Primary text page
280 TEXT : HOME : END
Note that it automatically relocates itself to $2000 if it is not
run at that address, so there's no need for "EXEC.ME.FIRST".
If run in Oasis at 4.7MHz, it syncs almost exactly with the
music--or with the original music video at:
http://www.youtube.com/watch?v=_zuIQkjm78o
It's kind of interesting to watch the two running simultaneously
in two windows. ;-)
-michael
NadaNet networking for Apple II computers!
Home page: http://members.aol.com/MJMahon/
"The wastebasket is our most important design
tool--and it's seriously underused."