[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
GS/OS Quad Boot
This was originally posted on comp.sys.apple2.marketplace in response to a
question, but I thought it really belongs here.
==============
GS/OS Quad Boot
==============
By Joel Buckley 11/7/2002
In an earlier post I described my quadruple boot.
Technically, you could call it a sextuple boot.
Startup Menu
0-exit to BASIC
1-run Copy II Plus
2-boot slot 6 (5.25 drive)
3-boot slot 5 (3.5 drive)
4-boot GSOS 4
5-boot GSOS 5.04
6-boot GSOS 6.01
Why all the choices?
Some software won't run off the hard disk-hence the floppy boot choices.
Some old GSOS programs don't work under System 6, hence the old GSOS
versions.
Since a couple of people have expressed interest, I present it here.
=============
THE PROGRAM
100 HOME
110 D$ = CHR$ (4)
120 PRINT D$"PR#3"
130 PRINT "Startup Menu 12/08/2001"
200 PRINT "0-exit to BASIC"
210 PRINT "1-run Copy II Plus"
220 PRINT "2-boot slot 6 (5.25 floppy drive)"
230 PRINT "3-boot slot 5 (3.5 floppy drive)"
240 PRINT "4-boot GS/OS 4"
250 PRINT "5-boot GS/OS 5.04"
260 PRINT "6-boot GS/OS 6.01"
300 VTAB 20: HTAB 5
310 PRINT "Select: "; CHR$ (7);
320 GET A$: IF A$ < "0" OR A$ > "6" THEN 300
330 A = VAL (A$): PRINT A$
340 ON A + 1 GOTO 900,1000,2000,3000,4000,5000,6000
890 :
900 REM exit to BASIC
910 END
990 :
1000 REM run Copy II Plus
1010 PRINT D$"-disk/copy2/util.system"
1020 END
1990 :
2000 REM boot slot 6 (5.25" floppy drive)
2010 PRINT D$"PR#6"
2020 END
2990 :
3000 REM boot slot 5 (3.5" floppy drive)
3010 PRINT D$"PR#5"
3020 END
3990 :
4000 REM boot GS/OS 4
4010 S$ = "4"
4020 GOTO 6100
4900 :
5000 REM boot GS/OS 5.04
5010 S$ = "5"
5020 GOTO 6100
5900 :
6000 REM boot GS/OS 6.01
6010 S$ = "6"
6090 :
6100 PRINT D$"open version"
6110 PRINT D$"read version"
6120 INPUT V$
6130 PRINT D$"close"
6140 IF V$ = S$ THEN 6400
6150 PRINT D$"rename system, system"V$
6160 PRINT D$"rename system"S$", system"
6170 PRINT D$"rename icons, icons"V$
6180 PRINT D$"rename icons"S$", icons"
6190 PRINT D$"rename basic.launcher, basic.l"V$
6200 PRINT D$"rename basic.l"S$", basic.launcher"
6210 PRINT D$"rename basic.system, basic.s"V$
6220 PRINT D$"rename basic.s"S$", basic.system"
6230 PRINT D$"rename boot.gs, boot.g"V$
6240 PRINT D$"rename boot.g"S$", boot.gs"
6300 PRINT D$"open version"
6310 PRINT D$"write version"
6320 PRINT S$
6330 PRINT D$"close"
6390 :
6400 PRINT D$"-BOOT.GS"
6410 END
=============
SETTING IT UP
Besides the menu program, you have to install the three different versions
of GS/OS and rename them.
Don't install the Basic startup menu program until you've set-up all the
other files.
Let's assume you have GS/OS System 6.01 installed.
The file in the root directory named PRODOS is actually a GSOS loader.
The real PRODOS8 version is named P8 and sits in the System folder.
Rename PRODOS as BOOT.G6.
Copy P8 to the root directory (copy, not move) and rename it PRODOS.
After boot, PRODOS8 will run the first file ending in.SYSTEM in the root
directory.
This is usually BASIC.SYSTEM.
BASIC.SYSTEM will run an Applesoft program named STARTUP in the root
directory.
Rename ICONS as ICONS6
Rename SYSTEM folder as SYSTEM6.
Rename BASIC.SYSTEM as BASIC.S6
Create a text file and name it BASIC.L6
Get out your GS/OS System 4 Install disks and run them.
When you are done, boot ProDOS8 off a floppy
Rename PRODOS as BOOT.G4
Rename ICONS folder as ICONS4
Rename SYSTEM folder as SYSTEM4
Rename BASIC.SYSTEM as BASIC.S4
Rename BASIC.LAUNCHER as BASIC.L4
Get out your GS/OS System 5 Install disks and run them.
When you are done, boot ProDOS8 off a floppy
Rename PRODOS as BOOT.G5
Rename ICONS folder as ICONS5
Rename SYSTEM folder as SYSTEM5
Rename BASIC.SYSTEM as BASIC.S5
Rename BASIC.LAUNCHER as BASIC.L5
When you are done, boot ProDOS8 off a floppy
Copy P8 from SYSTEM6/P8 to the root directory and rename it PRODOS.
Create a text file named version with contents of "6"
Rename BOOT.G6 as BOOT.GS
Rename BASIC.S6 as BASIC.SYSTEM
Rename BASIC.L6 as BASIC.LAUNCHER
Rename ICONS6 as ICONS
Rename SYSTEM6 as SYSTEM
Save the STARTUP program.
Whew!, You should be done.
============
EXPLANATION
The program is actually pretty simple.
If we want to stay in ProDOS8 we just exit.
Or add your favorite ProDOS8 programs to the menu.
Booting off floppies is straightforward.
Managing 3 versions of GSOS is a little more complicated.
We check the version number.
If it hasn't changed we just run BOOT.GS.
If it has changed, we rename all the standard files to .v files (where 'v'
is the current version.
Then we rename all the .s files to standard filenames (where 's' is the
newly selected version.
We update Version.
We run BOOT.GS.
Example:
If we select 6, first we check to see which version of GS/OS is active.
If its 6, we just run it with -BOOT.GS
If it was 5, first we rename BOOT.GS to BOOT.G5
Then we rename BOOT.G6 to BOOT.GS.
And so on with BASIC.SYSTEM, BASIC.LAUNCHER, ICONS, SYSTEM.
Then we change VERSION to 6.
Then we run it with -BOOT.GS.
=================
ADDITIONAL NOTES
If I remember correctly, System 4 (and maybe System 5) may not recognize
more than 2 hard drive partitions.
So, if you want to run old stuff off the hard drive, you must place it
there.
You may find a lot of the old stuff won't run off a hard drive.
Also, you should set your preferences on system 4 and system 6 to NOT save
finder information on disk. Otherwise, System 6 finder settings (like folder
colors) will be lost.
If the menu program ever gets interrupted, you will have to manually rename
the files and change VERSION to a known state.
System 4+5 used a program called BASIC.LAUNCHER. System 6 doesn't.
We just create a text file called BASIC.L6 to keep the renaming process the
same. This file is never used, only renamed.
I have a pretty large collection of software for the GS.
Much of it predates System 6.
Ssome of it doesn't work properly under System 6.
This setup let's me still use my hard disk with the earlier version
software.