Re: Apple II Music Video - Welcome to the Jungle!!

["Frank M." <frank_o_rama@hotmail.com>]

Here's the code for rendering the lores photoshop TIFFs onto the A2 GR
screen.....
(you can use CiderPress to drop them directly into a disk image)

The nice part is that you can use a modern computer and photoshop to
automate most of the de-resolutionating and palette bashing of the
original image.


Axl!!!! what happened to you!!!



10 REM **********************
20 REM *                    *
30 REM *RENDER MOVIE FRAMES *
40 REM *  by Frank Milliron *
50 REM *                    *
60 REM **********************
70 REM Set Frames to Convert
80 for n=1 to 6826
90 REM Add Leading Zeros
100  IF N < 10 THEN N$ = "000" + STR$ (N): GOTO 150
110  IF N >  = 10 AND N < 100 THEN N$ = "00" +  STR$ (N): GOTO 150
120  IF N >  = 100 AND N < 1000 THEN N$ = "0" +  STR$ (N): GOTO 150

130 n$=str$(n)

140 REM Load TIFF File
150 print chr$(4)+"PREFIX /GNR1/RAWFRAMES"
160 print chr$(4)+"BLOAD FRAME."+n$+".TIF,T$00,a$2000"

170 REM Find Signature Bytes
180 S=24000:home:vtab 10: ?"Now searching TIFF file #";N$:?"
for frame data..."
190 V=PEEK(S)
200 IF V=67 THEN s=s+1:v=peek(s):GOTO 220
210 S=S+1:GOTO 190
220 IF V=0 THEN s=s+1:v=peek(s):GOTO 240
230 S=S+1:GOTO 190
240 IF V=83 THEN s=s+1:v=peek(s):GOTO 260
250 S=S+1:GOTO 190
260 IF V=0 THEN s=s+1:v=peek(s):GOTO 280
270 S=S+1:GOTO 190
280 IF V=0 THEN s=s+1:v=peek(s):GOTO 300
290 S=S+1:GOTO 190
300 IF V=0 THEN s=s+1:v=peek(s):GOTO 320
310 S=S+1:GOTO 190
320 IF V=1 THEN s=s+1:v=peek(s):GOTO 340
330 S=S+1:GOTO 190
340 IF V=0 THEN s=s+1:GOTO 360
350 S=S+1:GOTO 190

360 REM RENDER FRAME AKA 6502 MELTDOWN
370  GR : POKE 49234,0
380  FOR Y = 0 TO 47
390  FOR X = 0 TO 39
400 V =  PEEK (S)
410  COLOR= V
420  PLOT X,Y
430 S = S + 1
440  NEXT X
450  NEXT Y

460 REM SAVE FRAME
470 PRINT chr$(4)+"PREFIX /GNR1/RENDERED"
480 PRINT  CHR$ (4)+"BSAVE FRAME."+N$+",A$400,L$400"

490 REM ON AND ON TILL THE BREAK OF DAWN
500 text:next n