Re: Apple II emulator for Mac

[rkneusel@carroll1.cc.edu (Ron Kneusel)]

To all:

Are you enjoying Kevin's Apple II+ emulator but having trouble
getting your old DOS 3.3 disks transfered?  This _might_ be of use to
you...

At the end of this post is a small Applesoft program to read a DOS 3.3
diskette to a file.  It _must_ be run under ProDOS, however, as it uses
the ProDOS READ_BLOCK and WRITE MLI commands.


Who should use this?
--------------------

This program is not going to be useful to everyone, in fact, it might
be useful to only a handful of people, but if it is, it should save 
you a good amount of time.

Use this program if one of the following applies to you:

1.  You have an Apple IIe, IIc or II+ with a RAM card bigger than 140K or
    a 3.5 inch floppy drive.  If you have the floppy you do not need
    the RAM card.
    
2.  You have access (like me) to a Mac LC series with an Apple IIe card.

3.  You have an Apple IIe, IIc or II+ with a RAM card bigger than 140K, a
    modem and an account somewhere (like on a Unix or VAX machine) with

    enough disk storage for the disk image file (143,360 bytes).
    
    
How to use it?
--------------

All users:    Get everything below the line '>> CUT HERE <<' into a

              text file on your Apple (remember, use only a ProDOS disk).
              At the prompt type EXEC DSK2FILE.TXT (assuming that's the
              name you used).  It will create the DSK2FILE program and
              associated DSK2FILE.X binary file.  Alternatively, you could
              simply type it in as it is short.
              
Group 1,2:    Run the program saving to the RAM card if you have it (it's
              much faster that way) and then copy the file to a 3.5 inch
              disk.  IIgs people do the same (or use a hard disk, etc.)
              If you don't have a RAM card use the drive, this is really
              kind of obvious.. get the file to a 3.5 inch disk somehow.
              Use Apple File Exchange on the Mac to copy the file to the

              Mac.  Use ResEdit to change the type to DSK5 and creator to
              A2EM. Repeat for each disk you want to transfer.
              
Group 3:      Run the program saving to the RAM card.  Use a terminal

              program to upload the file from the RAM card to the remote
              system.  Use a terminal program on the Mac to download it

              from the remote system (it is a binary file even though the

              catalog type is TXT).  Change the Mac type and creator as

              above and you are in business.  Of course, it you need to

              do this it might prove easier to use a null modem cable and

              go directly from Apple to the Mac.


I use a Mac LC to do the transfers and it works fine, though I imagine 
that the other methods should work just as well.  If you are having

difficulties let me know.

- Ron Kneusel  (kneusel@msupa.pa.msu.edu)

>>>>>>>>>>>>>>>> CUT HERE <<<<<<<<<<<<<<<<<

NEW
 10  REM DSK2FILE: 140K DISK TO A FILE, RTK
 11  D$ =  CHR$ (4)
 12  PRINT D$;"BLOAD DSK2FILE.X":BLK = 768:WRT = 784:HI = 780:LO = 779
 13  WTADDR = 796: GOSUB 100
 15  HOME : INVERSE : PRINT "DSK2FILE";: NORMAL 
 20  PRINT ": 140K DOS 3.3 TO FILE"
 25  PRINT "------------------------------"
 30  PRINT : INPUT "OUTPUT FILE ? ";F$
 35  PRINT D$;"CLOSE": PRINT D$;"OPEN ";F$
 40  PRINT : PRINT : PRINT "INSERT DISK IN S6,D1 & PRESS RETURN:";
 45  GET A$: IF A$ <  >  CHR$ (13) THEN 45
 46  PRINT
 50  FOR TK = 0 TO 34
 55  FOR SK = 0 TO 15
 60 B = 8 * TK + MAP(SK): REM  FIND PRODOS BLOCK
 61  VTAB 10: HTAB 1: CALL  - 868: PRINT "TRACK ";TK;", SECTOR ";SK
 63  POKE HI, INT (B / 256): POKE LO,B - 256 *  INT (B / 256)
 65  POKE WTADDR,HALF(SK): REM  SET PROPER BUFFER HALF
 70  CALL BLK: CALL WRT
 75  NEXT SK,TK
 80  PRINT D$;"CLOSE ";F$
 82  VTAB 13: PRINT "COMPLETE, ANOTHER ? (Y/N) ";
 85  GET A$: IF A$ = "Y" THEN 15
 90  END
 100  REM  LOAD DOS 3.3 -> PRODOS MAP
 105  DIM MAP(16),HALF(16)
 110  DATA  0,64,7,64,6,65,6,64,5,65,5,64,4,65,4,64
 112  DATA  3,65,3,64,2,65,2,64,1,65,1,64,0,65,7,65
 115  FOR I = 0 TO 15
 120  READ MAP(I),HALF(I)
 125  NEXT I: RETURN
SAVE DSK2FILE 
CALL -151
300: 20 00 BF 80 07 03 60 03
308: 60 00 40 09 00 00 00 00
310: 20 00 BF CB 19 03 B0 0A
318: 60 04 01 00 40 00 01 00
320: 00 00 20 DA FD 60 00 00
BSAVE DSK2FILE.X,A$300,E$327