Re: phone card type program for Apple IIe? text search algorithm?

[aiiadict@gmail.com]

aiiadict@gmail.com wrote:
>
>  (basic code snipped)


load and save work in this ....

anyone know of a nibble article, or maybe
assemblylines, etc, that has a good text
search algorithm?

 20  DIM NAMES$(100),NUMBER$(100),A1DDRES$(100),A2DDRES$(100)
 30 NN = 1: REM  # of phone numbers
 40 CN = 1: REM   current # being             displayed
 90  HOME
 100  VTAB 1: PRINT "phone list"
 110  VTAB 5: PRINT "1)load"
 120  VTAB 7: PRINT "2)save"
 130  VTAB 9: PRINT "3)edit"
 140  VTAB 11: PRINT "4)SEARCH"
 150  VTAB 13: PRINT "5)ADD"
 200  VTAB 17: PRINT "name ";NAMES$(CN)
 210  VTAB 18: PRINT "number ";NUMBER$(CN)
 220  VTAB 19: PRINT "address line1 ";A1DDRES$(CN)
 230  VTAB 20: PRINT "address line2 ";A2DDRES$(CN)
 300  VTAB 1: HTAB 20: PRINT "NN ";NN;" CN ";CN
 500  GET I$
 510  IF I$ = "1" THEN  GOSUB 1000: GOTO 90
 520  IF I$ = "2" THEN  GOSUB 2000: GOTO 90
 530  IF I$ = "3" THEN  GOSUB 3000
 540  IF I$ = "4" THEN  GOSUB 4000
 550  IF I$ = "5" THEN NN = NN + 1
 600  IF I$ = "J" THEN CN = CN - 1: IF CN < 1 THEN CN = NN
 610  IF I$ = "L" THEN CN = CN + 1: IF CN > NN THEN CN = 1
 620  IF I$ = "J" OR I$ = "L" THEN  HOME : GOTO 100
 700  GOTO 200
 999  REM : LOAD
 1000  INPUT "name of list to open ";A$
 1010  PRINT  CHR$ (4);"open ";A$
 1020  PRINT  CHR$ (4);"read ";A$
 1030  INPUT NN: REM  number of numbers :-)
 1040  FOR I = 1 TO NN
 1050  INPUT NAMES$(I)
 1060  INPUT NUMBER$(I)
 1070  INPUT A1DDRES$(I)
 1080  INPUT A2DDRES$(I)
 1085  NEXT I
 1090  PRINT  CHR$ (4);"close ";A$
 1100  RETURN
 1999  REM : SAVE
 2000  INPUT "name of list to SAVE ";A$
 2010  PRINT  CHR$ (4);"open ";A$
 2020  PRINT  CHR$ (4);"write ";A$
 2030  PRINT NN: REM  number of numbers :-)
 2040  FOR I = 1 TO NN
 2050  PRINT NAMES$(I)
 2060  PRINT NUMBER$(I)
 2070  PRINT A1DDRES$(I)
 2080  PRINT A2DDRES$(I)
 2085  NEXT I
 2090  PRINT  CHR$ (4);"close ";A$
 2100  RETURN
 3000  VTAB 17: HTAB 6: INPUT "";NAMES$(CN)
 3010  VTAB 18: HTAB 8: INPUT "";NUMBER$(CN)
 3020  VTAB 19: HTAB 15: INPUT "";A1DDRES$(CN)
 3030  VTAB 20: HTAB 15: INPUT "";A2DDRES$(CN)
 3040  RETURN
 4000  VTAB 20: PRINT "SEARCH NOT WORKING YET";
 4010  RETURN